*
* Simple joystick menu/gui system
*
* Uses ZP pointer $fc-$ff
*
* s. judd
* 12/30/05
*

 rel

put 'core.ext.s'

MAXJOYITEMS EQU 16

*
* Menu Item types:
*   0 - empty (text only)
*   1 - number (min..max)
*   2 - list (item, enumeration)
*   3 - input
*

JOYEMPTYITEM equ 0
JOYNUMITEM equ 1
JOYLISTITEM equ 2
JOYINPUTITEM equ 3


deftype JoyMenu
  uint .labelptr(MAXJOYITEMS)
  ubyte .type(MAXJOYITEMS)
  uint .varptr(MAXJOYITEMS)
  uint .listptr(MAXJOYITEMS)
  ubyte .listsize(MAXJOYITEMS)
  ubyte .min(MAXJOYITEMS)
  ubyte .max(MAXJOYITEMS)
  uint .firecallback(MAXJOYITEMS)
  uint .lrcallback(MAXJOYITEMS)

  ubyte .row(MAXJOYITEMS)
  ubyte .col(MAXJOYITEMS)
  ubyte .width(MAXJOYITEMS)
  ubyte .numchars(MAXJOYITEMS);number of chars printed to screen
defend

type JoyMenu NewJoyMenu
ubyte JoyMenuLength
ubyte JoyMenuRow
ubyte JoyMenuCol
ubyte JoyMenuWidth
ubyte JoyCurItem
ubyte JoyOrientation
*ubyte JoyMenuID


*-------------------------------
*
* Test code
*
*-------------------------------

  do 0
ubyte testlist(10,16) = [ &
  ['Fender'] &
  ['Gibson'] &
  ['Carvin'] &
  ['PRS   '] &
]
ubyte testvars(10) = [1 2 3 14 5 16 7 18 9 10]
ubyte testinput(16) = ['hola']
ubyte count

NewMenu(1, 5, 2, 8, 1)
AddMenuItem(#'Numtest', JOYNUMITEM, #testvars(0))
SetMinMax(0,17)
AddMenuItem(#'Axe', JOYLISTITEM, #testvars(1))
SetEnumList(#testlist, 16)
SetMinMax(0,3)
SetFireCallback(#testback)
AddMenuItem(#'Name', JOYINPUTITEM, #testinput)
SetMenuRowCol(5,18)
SetMinMax(0,13)
AddMenuItem(#'number2', JOYNUMITEM, #testvars(4))
SetMinMax(12,19)
testvars(4)=13
AddMenuItem(#' ', JOYEMPTYITEM, #' ')


DisplayMenu()

repeat
  count=0
  while count<8
    wait $d012,255
    wait $d012,0
    inc count
  endwhile
  RunMenu()
forever

 waitchar

done

sub testback()
  sprint(0,0) "bang!"
endsub

  fin


*
* Create new menu
*
sub ent NewMenu(ubyte newid, ubyte row, ubyte col, ubyte width, ubyte hv)_byte id
  id = newid
*  JoyMenuID = newid
  JoyMenuLength = 0
  JoyMenuRow = row
  JoyMenuCol = col
  JoyMenuWidth = width
  JoyOrientation = hv     ;0/1
  JoyCurItem = 0
endsub

*
* Add menu item
*
sub ent AddMenuItem(uint label, ubyte type, uint variable)
  ubyte k

  k = JoyMenuLength

  NewJoyMenu.labelptr(k) = label
  NewJoyMenu.type(k) = type
  NewJoyMenu.varptr(k) = variable
  NewJoyMenu.row(k) = JoyMenuRow
  NewJoyMenu.col(k) = JoyMenuCol
  NewJoyMenu.width(k) = JoyMenuWidth
  NewJoyMenu.firecallback(k) = 0
  NewJoyMenu.lrcallback(k) = 0

  UpdateRowCol()
  inc JoyMenuLength
  JoyCurItem = JoyMenuLength-1
endsub

sub UpdateRowCol()
  if+ JoyOrientation
    inc JoyMenuRow
  else
    JoyMenuCol = JoyMenuCol + (JoyMenuWidth << 1)
  endif
endsub

*
* Get/Set current item
*
sub ent GetCurrentItem()_ubyte curitem
  curitem = JoyCurItem
endsub

sub ent SetCurrentItem(ubyte curitem)
  JoyCurItem = curitem
endsub

*
* Reset row/col
*
sub ent SetMenuRowCol(ubyte row, ubyte col)
  NewJoyMenu.row(JoyCurItem)=row
  NewJoyMenu.col(JoyCurItem)=col
  JoyMenuRow = row
  JoyMenuCol = col
  UpdateRowCol()
endsub

*
* Setup enumerated list
*
sub ent SetEnumList(uint list, ubyte dimsize)
  ubyte k

  k = JoyCurItem

  NewJoyMenu.listptr(k) = list
  NewJoyMenu.listsize(k) = dimsize
  NewJoyMenu.min(k) = 0
endsub

*
* Setup number min/max
*
sub ent SetMinMax(ubyte min, ubyte max)
  ubyte k

  k = JoyCurItem
  NewJoyMenu.min(k) = min
  NewJoyMenu.max(k) = max
endsub

*
* Set callback routine (fire button)
*
sub ent SetFireCallback(uint addr)
  NewJoyMenu.firecallback(JoyCurItem) = addr
endsub

sub ent SetLRCallback(uint addr)
  NewJoyMenu.lrcallback(JoyCurItem) = addr
endsub

*
* Display menu
*
sub ent DisplayMenu()
  ubyte k

  for k=0:JoyMenuLength-1
    PrintMenuItem(k)
  next

  HighlightItem()
endsub

*
* Print single item
*
sub PrintMenuItem(ubyte k)

  ubyte j,temp
  ubyte row,col,col2
  ubyte jtype
  ubyte str(32)

  row = NewJoyMenu.row(k)
  col = NewJoyMenu.col(k)
  col2 = col + JoyMenuWidth

  jtype = NewJoyMenu.type(k)
  CopyString(NewJoyMenu.labelptr(k), #str)
  sprint(row,col) str$

  if+ (jtype = JOYNUMITEM)
    temp = GetMenuValue(k)_val
    JoyPrintNum(temp, row, col2)
    NewJoyMenu.numchars(k)=2
  elsif+ (jtype = JOYLISTITEM)
    JoyPrintList(k, row, col2)
    NewJoyMenu.numchars(k) = JoyPrintList_numchars
  elsif+ (jtype = JOYINPUTITEM)
    JoyPrintInput(k, row, col2)
    NewJoyMenu.numchars(k) = JoyPrintInput_numchars
  else
    NewJoyMenu.numchars(k) = 0
  endif

endsub


*
* Cheese num2str
*
sub JoyPrintNum(ubyte temp, ubyte row, ubyte col)
*  ubyte screen(25,40)@$0400
  ubyte j
  ubyte num(4)

  j = 0
  if+ (temp>=100)         ;cheese num2str
    num$ = '000'
    j=2
  elsif+ temp>=10
    num$ = '00 '
    j=1
  else
    num$ = '0  '
    j=0
  endif
  while+ (temp>=100)
    num(0) = num(0)+1
    temp=temp-100
  endwhile+
  while+ (temp>=10)
    num(j-1) = num(j-1)+1
    temp=temp-10
  endwhile+
  while+ (temp>=1)
    num(j) = num(j)+1
    temp=temp-1
  endwhile+
*  screen$(row,col) = num$(0:2)
  sprint(row,col) num$

endsub

*
* Print the current list item
*

sub JoyPrintList(ubyte k, ubyte row, ubyte col)_ubyte numchars
*  ubyte screen(25,40)@$0400
  ubyte temp,j,size
  ubyte str(32)
  uint zp@$fc

  temp = GetMenuValue(k)_val
  size = NewJoyMenu.listsize(k)
  zp = NewJoyMenu.listptr(k)
  j = 0
  while+ j<temp
    zp = zp+size
    j=j+1
  endwhile+

  CopyString(zp, #str)
  numchars = CopyString_numchars

*  screen$(row,col) = str$(0:numchars)
  sprint(row,col) str$
endsub

*
* Print an input item (string)
*
sub JoyPrintInput(ubyte k, ubyte row, ubyte col)_ubyte numchars
*  ubyte screen(25,40)@$0400
  ubyte str(32)
  uint zp@$fc

  CopyString(NewJoyMenu.varptr(k), #str)
  numchars = CopyString_numchars

*  screen$(row,col) = str$(0:numchars)
  sprint(row,col) str$
endsub

*
* Run/Update menu: get input, highlight selection, etc.
*
sub ent RunMenu()
  ubyte temp
  ubyte joy2@$dc00

  temp = joy2 biteor 255
  testall
    case+ temp=0          ;do nothing

    case+ temp bitand 1    ;up
      HighlightItem()
      if+ JoyCurItem > 0
        dec JoyCurItem
      endif
      HighlightItem()

    case+ temp bitand 2    ;down
      HighlightItem()
      if+ JoyCurItem < JoyMenuLength-1
        inc JoyCurItem

      endif
      HighlightItem()

    case+ temp bitand 4    ;left
      EraseItem()
      JoyLeft()
      PrintMenuItem(JoyCurItem)
      HighlightItem()
      CallCallback(NewJoyMenu.lrcallback(JoyCurItem))

    case+ temp bitand 8    ;right
      EraseItem()
      JoyRight()
      PrintMenuItem(JoyCurItem)
      HighlightItem()
      CallCallback(NewJoyMenu.lrcallback(JoyCurItem))

    case+ temp bitand 16   ;fire
      CallCallback(NewJoyMenu.firecallback(JoyCurItem))

    case! temp bitand 16

  endtest
endsub


sub JoyLeft()
  ubyte temp
  ubyte jtype
  ubyte k

  k = JoyCurItem
  jtype = NewJoyMenu.type(k)

  if+ (jtype = JOYNUMITEM) or (jtype = JOYLISTITEM)
    temp = GetMenuValue(k)_val
    if+ temp>NewJoyMenu.min(k)
      SetMenuValue(k, temp-1)
    endif
  endif
endsub

sub JoyRight()
  ubyte temp
  ubyte jtype
  ubyte k
  ubyte row,col
  ubyte str(32)

  k = JoyCurItem
  jtype = NewJoyMenu.type(k)

  if+ (jtype = JOYNUMITEM) or (jtype = JOYLISTITEM)
    temp = GetMenuValue(k)_val
    if+ temp<NewJoyMenu.max(k)
      SetMenuValue(k, temp+1)
    endif
  elsif (jtype = JOYINPUTITEM)
    row = NewJoyMenu.row(k)
    col = NewJoyMenu.col(k) + JoyMenuWidth
    str$ = "                                "
    sprint(row,col) str$(0:NewJoyMenu.numchars(k))
    sprint(row,col)
    CopyString(NewJoyMenu.varptr(k), #str)
    InputStr(NewJoyMenu.max(k)) str$
*    Input str$
    CopyString(#str, NewJoyMenu.varptr(k))
  endif
endsub

sub CallCallback(uint addr)
  if+ addr != 0
    jmp (addr)
  endif
endsub


*
* Highlight/de-highlight current item
*

sub EraseItem()
  HighErase(0)
endsub

sub HighlightItem()
  HighErase(1)
endsub

sub HighErase(ubyte flag)
  ubyte row,col,col2,len,k
  ubyte screen(25,40)@$0400

  row = NewJoyMenu.row(JoyCurItem)
  col = NewJoyMenu.col(JoyCurItem)
  col2 = col + NewJoyMenu.width(JoyCurItem)
  len = NewJoyMenu.numchars(JoyCurItem)

  if+ len != 0
    for+ k=col2:col2+len
      if+ flag
        screen(row,k) = screen(row,k) eor $80
      else
        screen(row,k) = 32
      endif
    next+
  endif
endsub


*
* Retrieve/Set the value from the menu var
*
sub GetMenuValue(ubyte k)_ubyte val
  uint zp1@$fc

      zp1= NewJoyMenu.varptr(k)
      ldy #00             ;yup, need a pointer type/mode
      lda (zp1),y
      sta val
endsub

sub SetMenuValue(ubyte k, ubyte val)
  uint zp1@$fc

      zp1= NewJoyMenu.varptr(k)
      ldy #00             ;yup, need a pointer type/mode
      lda val
      sta (zp1),y
endsub

*
* Copy a string from one pointer to another
*
sub CopyString(uint src, uint dest)_ubyte numchars

  uint zp1@$fc, zp2@$fe

  zp1=src                 ;this ensures we don't overwrite
  zp2=dest                ;passed-in zp vars

  ldy #00
:l1
  lda (zp1),y
  sta (zp2),y
  beq :c1                 ;null term
  iny
  bne :l1
:c1
  dey
  sty numchars            ;number of chars in string
endsub


 do 0

*
* Below should really all be in putcore
* but is hacked in here.
*

*put 'putcore.e.s'

SlangOut

CHROUT = $ffd2
GETIN = $ffe4
STOP                      =$FFE1
BLNSW                     =$CC
BLNON                     =$CF
BLNCT                     =$CD

*
* INPUT inputs a string of data into STRBUF.  The maximum
* number of chars to be read are passed in X.  On output,
* zero set means the input was aborted with R/S or is
* empty.  .A (and STRLEN) contains the string length.
*
STRBUF                    EQU $0200
STRLEN                    ;ENT
         DFB 00
MAXLEN                    DFB 00

]INPUT
         LDA #00
         STA STRBUF
INPUT2                    STA STRLEN
         STX MAXLEN
         LDA $0286        ;Set blink color to
         STA $0287        ;current color.

:LOOP    LDA #1
         STA BLNCT
         LDA #00
         STA BLNSW        ;Blink
:W                        LDA BLNON
         BNE :W           ;Wait for one blink

:WAIT                     JSR GETIN
         BNE :BLOFF
         JSR STOP
         BNE :WAIT
         LDA #00
:BLOFF                    LDY #1
         STY BLNCT
:WAIT2                    LDY BLNON
         BEQ :WAIT2
         INC BLNSW

         TAY
         BEQ :RTS
         CMP #160         ;Alphanumeric characters
         BCS :NORMAL
         CMP #147
         BEQ :CLR
         CMP #128
         BCS :LOOP
         CMP #13
         BEQ :DONE
         CMP #20
         BEQ :DEL
         CMP #32
         BCC :LOOP
:NORMAL
         LDY STRLEN
         CPY MAXLEN
         BCS :LOOP
         STA STRBUF,Y
         JSR CHROUT
         INC STRLEN
         BNE :LOOP

:CLR                      LDYSTRLEN
         BEQ              :LOOP
         LDA              #20
:L2                       JSRCHROUT
         DEC              STRLEN
         BNE              :L2
         BEQ              :LOOP

:DEL                      LDY STRLEN
         BEQ :LOOP
         LDA #157
         JSR CHROUT
         LDA #32
         JSR CHROUT
         LDA #157
         JSR CHROUT
         DEC STRLEN
         BPL :LOOP

:DONE                     LDY STRLEN
         LDA #00
         STA STRBUF,Y
         TYA              ;Z set if string empty
:RTS                      RTS

SlangIn

sub asm ]InputStr@]INPUT(@x)_uint buffer@STRBUF;InputStr(maxchars)

 fin